2001년 12월로 총 22,698 건의 데이터가 생성되었다. 하지만 도대체 몇 건이 삭제되었고, 몇 건이 입력되었으며, 몇 건이 갱신되었는지 알 수가 없다. 이런 내용은 SQL%ROWCOUNT와 DBMS_OUTPUT.PUT_LINE 프로시저를 사용하면 쉽게 알 수 있는데, 프로시저에 이 부분을 추가해 보자.

입력

    CREATE OR REPLACE PACKAGE BODY ch17_src_test_pkg IS

      PROCEDURE sales_detail_prc ( ps_month IN VARCHAR2,
                                   pn_amt   IN NUMBER,
                                   pn_rate  IN NUMBER   )
    IS

    BEGIN
      DBMS_OUTPUT.PUT_LINE('--------------<변수값 출력>---------------------');
      DBMS_OUTPUT.PUT_LINE('ps_month : ' || ps_month);
      DBMS_OUTPUT.PUT_LINE('pn_amt   : ' || pn_amt);
      DBMS_OUTPUT.PUT_LINE('pn_rate  : ' || pn_rate);
      DBMS_OUTPUT.PUT_LINE('------------------------------------------------');

      --1. p_month에 해당하는 월의 CH17_SALES_DETAIL 데이터 삭제
      DELETE ch17_SALES_DETAIL
       WHERE sales_month = ps_month;

      DBMS_OUTPUT.PUT_LINE('DELETE 건수 : ' || SQL%ROWCOUNT);

      --2. p_month에 해당하는 월의 CH17_SALES_DETAIL 데이터 생성
      INSERT INTO ch17_SALES_DETAIL
      SELECT b.prod_name,
             d.channel_desc,
             c.cust_name,
             e.emp_name,
             a.sales_date,
             a.sales_month,
             sum(a.quantity_sold),
             sum(a.amount_sold)
       FROM sales a,
             products b,
             customers c,
             channels d,
             employees e
       WHERE a.sales_month = ps_month
         AND a.prod_id     = b.prod_id
         AND a.cust_id     = c.cust_id
         AND a.channel_id  = d.channel_id
         AND a.employee_id = e.employee_id
       GROUP BY b.prod_name,
                d.channel_desc,
                c.cust_name,
                e.emp_name,
                a.sales_date,
                a.sales_month;

      DBMS_OUTPUT.PUT_LINE('INSERT 건수 : ' || SQL%ROWCOUNT);

      -- 3. 판매금액(sales_amt)이 pn_amt보다 큰 건은 pn_rate 비율만큼 할인
      UPDATE ch17_SALES_DETAIL
         SET sales_amt = sales_amt - ( sales_amt * pn_rate * 0.01)
       WHERE sales_month = ps_month
         AND sales_amt   > pn_amt;

      DBMS_OUTPUT.PUT_LINE('UPDATE 건수 : ' || SQL%ROWCOUNT);

      COMMIT;

      DBMS_OUTPUT.PUT_LINE('여기서의 값은???? : ' || SQL%ROWCOUNT);

      EXCEPTION WHEN OTHERS THEN
        DBMS_OUTPUT.PUT_LINE(SQLERRM);
        ROLLBACK;
      END sales_detail_prc;
    END ch17_src_test_pkg;

결과

    PACKAGE BODY CH17_SRC_TEST_PKG이(가) 컴파일되었습니다.